[ADO] 중복제거 후 합계

http://kin.naver.com/qna/detail.nhn?d1id=1&dirId=102020101&docId=264482360

중복제거된 품목을 출력하고 품목별 수량을 합계낸 결과물.

품목이 두개 이상인 것만 출력한다.

Option Explicit
 
Sub Macro()
 
    Dim ADO_Connect As New ADODB.Connection
    Dim ADO_Record As New ADODB.Recordset
    Dim sql As String
    Dim ExcelVersion As Integer
    Dim OLEDB_Connect As String
    
    '파일 버전을 확인하여 OLEDB를 사용할 버전을 정합니다.
    'ADO에 기본으로 들어가는 내용입니다.
    Select Case Application.Version
        Case Is <= 11: ExcelVersion = 8
        Case Is >= 12: ExcelVersion = 12
        Case Else
            MsgBox "엑셀 버전을 확인해주세요"
            Exit Sub
    End Select
    
    OLEDB_Connect = "Provider=Microsoft.Ace.OLEDB.12.0;" & _
                "Data Source='" & ThisWorkbook.FullName & "';" & _
                "Extended Properties =""Excel " & ExcelVersion & ".0 xml; HDR = YES"";"
            
    '기존자료 삭제
    Range("G6").CurrentRegion.Offset(1).ClearContents
    
    'SQL을 지정합니다.
    sql = "SELECT 품목, sum(수량) " '중복제거 된 품목과 품목별 수량합계를 출력합니다.
    sql = sql & "FROM [Sheet1$" & Range("C6").CurrentRegion.Address(0, 0) & "] "    '데이터 영역입니다.
    sql = sql & "GROUP BY 품목 HAVING count(품목)>1"    '품목이 2개 이상인 것만 가져옵니다.
    
    'ADO 및 레코드셋에 ADO_Connect
    ADO_Connect.Open OLEDB_Connect
    ADO_Record.Open sql, ADO_Connect, 3, 3, 1
    
    'G6셀에 검색 결과를 출력합니다. 검색결과가 없으면 공란을 출력합니다.
    Range("G6").CopyFromRecordset ADO_Record
 
    '변수 초기화
    ADO_Record.Close
    ADO_Connect.Close
    
    Set ADO_Record = Nothing
    Set ADO_Connect = Nothing
    
End Sub
 
 

예시.xlsm